Postsync update gentoo

2026-09-14 15:02:01 +02:00
parent 366582b3b9
commit 495e179163
3 changed files with 103 additions and 0 deletions
@@ -4,3 +4,4 @@ DIST intel-compute-runtime-26.09.37435.10.tar.gz 8834318 BLAKE2B 85240f23ae7ec11
 DIST intel-compute-runtime-26.18.38308.1.tar.gz 8897722 BLAKE2B 149ade89a80c27c0ff331c94ab2594eeb65914174781254f9c5eaf472331ac3d62c0b6a932b840c7e7e14903166f6322a7b09cbfb0a2a1554add30026294263d SHA512 30868b7f3338c177521e93d59fb5c2146bcafa905e92af6d1ea224de9069b7c6dba91f09df71be7d587a1b4a8682a9dae949036c8100d18d038ec9c9736314e3
 DIST intel-compute-runtime-26.22.38646.4.tar.gz 9173397 BLAKE2B aa234d0d244f300db1bd4244674f1a89c62c2c4691fa68cee2971f2fdab3bed872e2929d93be6e4227c05c7e3f672de66c6179d030138d370dc7a168c9fd115b SHA512 16bacf6b030bcc292bee16f964936bcb13ef6e3f12e76aa4cdee807dd1a3b9b32dca49a0cb3cc59e62b616a1662389db4505e6b05edaef10c9ca67a73bbc77d1
 DIST intel-compute-runtime-26.27.39122.12.tar.gz 9384549 BLAKE2B b929ac2d1d0a7d064500b7d78dcb008a441d07e9348d25798d6fc319cf62a39050910be93f5ea1516c44b36dcd7fbb922304d7dacab02c4c35a5e616840655b5 SHA512 df75b82dba99852a71497fe99b0e974454a1aa9b96623f54efd978d10cb51513aef4d94d774ff5f2ee3c266a7dc4cd90efd0e9b1b9bd1164d9b0b9d1879f30a6
+DIST intel-compute-runtime-26.31.39395.14.tar.gz 9420076 BLAKE2B 8ba4caf6c4853c7d6ef5ad6f8253f3c6fe6c5188cbf41455a60f87252214e2fb2cf717dc1f4593d3e3445330bd68952f6ec6418d265c16a7ae26db12571d6cb8 SHA512 1f002c703bd82a1d447a5ea7fda97620ba127fce7cdc2833e6322a2d3c3bec4a062b0a2ffbd192aa67c458b5f2391dc68eacba9c92fbde65b617174efdddf8d5
@@ -0,0 +1,87 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0/1.6.$(ver_cut 3)"
+KEYWORDS="~amd64"
+IUSE="disable-mitigations +l0 +vaapi"
+
+RDEPEND="
+	!dev-libs/intel-compute-runtime:legacy
+	>=dev-util/intel-graphics-compiler-2.41.5:0
+	!dev-util/intel-graphics-compiler:legacy
+	>=media-libs/gmmlib-22.10.1:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.231:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-1.3.2:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( <dev-libs/level-zero-1.33.1:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "Security.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO_DISABLE_MITIGATIONS="$(usex disable-mitigations)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}