Postsync update gentoo

2026-05-14 20:01:16 +02:00
parent 6437308883
commit 55cf019bf2
43 changed files with 284 additions and 36 deletions
@@ -1,3 +1,4 @@
 DIST intel-compute-runtime-25.31.34666.3.tar.gz 8030033 BLAKE2B e80bd3ca184b17b5243a6d84b68c5ae76dec6d3d1108e4e0de395db82f28facf20c352289cf3ffd7565929b934f04ef6309f336c7c67d1182c91e43507f60f17 SHA512 1ca6f411e17f18912a0137babdc5322e2d9c97da96ce302de9e78b652c3e40b98f9ed85785bcb68d305bd7f25e37f0c2a34391ed62202d4b08161e569c7b4eea
 DIST intel-compute-runtime-26.05.37020.3.tar.gz 8658816 BLAKE2B be4c37c29604efd4e04dc6ba887d5e9a6cc7fe64792493049fe23f90350932b46ea7b7c301c6b28ceea49e2c393f83dc9b0ec1842e93a4efc868f63e999f343e SHA512 eabd9a5076a2059b2cc64b264671db348b64ccbd646a596d548523e3dd7f4badecc6f8e1d9dde908ad13ce1da32ef706e4587be052f2f3063db6c909e7d22704
 DIST intel-compute-runtime-26.09.37435.10.tar.gz 8834318 BLAKE2B 85240f23ae7ec111f9be26112ff639f59e182aed8ad34dd465b42c9bd13c869df76a8e3efdf181b2e5dfe848f21c346803795b9ed3eefaa317986d65b16a53e1 SHA512 b28ceedf42fc5114700db0665593d82e1e503fa46baaf3a2be12258b7e9949c0b94304b0a67f99015469979935d3d8692a0a641cb2c0c8718cecced9b0737f7b
+DIST intel-compute-runtime-26.18.38308.1.tar.gz 8897722 BLAKE2B 149ade89a80c27c0ff331c94ab2594eeb65914174781254f9c5eaf472331ac3d62c0b6a932b840c7e7e14903166f6322a7b09cbfb0a2a1554add30026294263d SHA512 30868b7f3338c177521e93d59fb5c2146bcafa905e92af6d1ea224de9069b7c6dba91f09df71be7d587a1b4a8682a9dae949036c8100d18d038ec9c9736314e3
@@ -0,0 +1,87 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0/1.6.$(ver_cut 3)"
+KEYWORDS="~amd64"
+IUSE="disable-mitigations +l0 +vaapi"
+
+RDEPEND="
+	!dev-libs/intel-compute-runtime:legacy
+	>=dev-util/intel-graphics-compiler-2.35.2:0
+	!dev-util/intel-graphics-compiler:legacy
+	>=media-libs/gmmlib-22.9.0:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.209.1:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-1.2.0:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.28.6:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO_DISABLE_MITIGATIONS="$(usex disable-mitigations)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}