Postsync update gentoo

dev-python/proton-core/Manifest

@@ -0,0 +1 @@
+DIST proton-core-0.7.0.tar.gz 78329 BLAKE2B f2733bb3a9921721fbc93ef694d809f65db7b104b0a1301c25046fd0a8d816202da1b7b6da73fe2320b533075d9d4114673b22c7a765502c11cd0943818a4565 SHA512 47d47d702c493a2eefbcd0a544d3b877ac16176a66bd5a24fa558cc02287807a6a5c44a8ef23830d3c81a0f52e7109fba5984cd736b754735bf3a23ccb9a2822

dev-python/proton-core/proton-core-0.7.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Proton Technologies API wrapper"
+HOMEPAGE="https://github.com/ProtonVPN/python-proton-core/"
+SRC_URI="https://github.com/ProtonVPN/python-proton-core/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/python-${P}"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/pyotp[${PYTHON_USEDEP}] )"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/bcrypt[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/python-gnupg[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -i "/--cov/d" setup.cfg || die
+}
+
+python_test() {
+	# The following tests need network
+
+	EPYTEST_DESELECT=(
+		"tests/test_alternativerouting.py::TestAlternativeRouting::test_alternative_routing_works_on_prod"
+		"tests/test_autotransport.py::TestAuto::test_auto_works_on_prod"
+		"tests/test_protonsso.py::TestProtonSSO::test_broken_data"
+		"tests/test_protonsso.py::TestProtonSSO::test_broken_index"
+		"tests/test_protonsso.py::TestProtonSSO::test_sessions"
+		"tests/test_session.py::TestSession::test_ping"
+		"tests/test_session.py::TestSession::test_raw_ping"
+		"tests/test_tlsverification.py::TestTLSValidation::test_bad_pinning_fingerprint_changed"
+		"tests/test_tlsverification.py::TestTLSValidation::test_bad_pinning_url_changed"
+		"tests/test_tlsverification.py::TestTLSValidation::test_successful"
+		"tests/test_tlsverification.py::TestTLSValidation::test_without_pinning"
+	)
+
+	XDG_RUNTIME_DIR="${T}/python_test" epytest
+}