Postsync update gentoo

www-client/google-chrome/Manifest

@@ -8,3 +8,4 @@ DIST google-chrome-stable_137.0.7151.68-1_amd64.deb 117334784 BLAKE2B d0a9a885e3
 DIST google-chrome-stable_138.0.7204.157-1_amd64.deb 118188228 BLAKE2B 5970a6c8461a92a8c4e57dade81625b15265e3b4cfdcbbdb47c589940acd5c2a7d912fcea1913a65e20bf5cc85892241dd60dedd5e7371c7e424aac286613d54 SHA512 a77f69bd52fff52bdcd151dc9da8a7a8acd1831e0ff7824683ac1663b3a19281cd00dfc99c1f4c01ec8b7cab36c533a8344a6fe9bc89384fb6c34d25b92b9274
 DIST google-chrome-stable_139.0.7258.127-1_amd64.deb 118698388 BLAKE2B a73dc9b01e57293940f93636d4814b982d67987b6eebc694a017017028643bd77ade12eeb7ccfb220781888f0c4d1f5ce07caac558879883d36072855d8e0784 SHA512 69d4c8111096b2a04c91e51348740d7460aecb8ff267aa8b97e4d73a0ca8d7c8f694a7c068f1f56b19952611c3a0f130a1e6bad90781a0d7a235ba494e88e83a
 DIST google-chrome-stable_139.0.7258.154-1_amd64.deb 118595680 BLAKE2B d2658400505bb6f69fad13d64671b6467a411dee1e1153c67923f61e282824d79c8eecf59b00688599f8fb4119db52a5c388edcd18744970ca33d73a7f3ca9f1 SHA512 42db46ce5553ac580db97e4983ce716a47de0fc68711ddd69aa17595e7ab2505d5df6ef6f8dfb4288c42a2bf4cce784db7d6b17addf9fedb2a0bfa07825a1f5f
+DIST google-chrome-stable_140.0.7339.80-1_amd64.deb 120610648 BLAKE2B 3e89ac5712dfa7424f4ef76d157968a8ee2e883222786b37c29c3cc689426446565dda745923082d62894435d1b70f9e987852026c2fcd38e91f1c085e412abb SHA512 c37b05ae25c8184affa52cdf8b1bee4de511bc3c3649a61bc95f963f5ae2ca6207b0dfee7af8ce6deb7ce752e79fb6aaf6c1bfc798b447fd2a5d7060f60a8d88

www-client/google-chrome/google-chrome-140.0.7339.80.ebuild

@@ -0,0 +1,125 @@
+# Copyright 2011-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB es es-419 et fa fi fil fr gu he
+	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr
+	sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop pax-utils unpacker xdg
+
+DESCRIPTION="The web browser from Google"
+HOMEPAGE="https://www.google.com/chrome/"
+
+if [[ ${PN} == google-chrome ]]; then
+	MY_PN=${PN}-stable
+else
+	MY_PN=${PN}
+fi
+
+MY_P="${MY_PN}_${PV}-1"
+SRC_URI="https://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb"
+S=${WORKDIR}
+
+LICENSE="google-chrome"
+SLOT="0"
+KEYWORDS="-* amd64"
+
+IUSE="qt6 selinux"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	>=dev-libs/nss-3.26
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	sys-libs/libcap
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	|| (
+		x11-libs/gtk+:3[X]
+		gui-libs/gtk:4[X]
+	)
+	x11-libs/libdrm
+	>=x11-libs/libX11-1.5.0
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+	selinux? ( sec-policy/selinux-chromium )
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/google-chrome.*\\.desktop"
+CHROME_HOME="opt/google/chrome${PN#google-chrome}"
+
+pkg_nofetch() {
+	eerror "Please wait 24 hours and sync your tree before reporting a bug for google-chrome fetch failures."
+}
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "google-chrome only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	rm -r etc usr/share/menu || die
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+	gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
+	if [[ -L usr/share/man/man1/google-chrome.1.gz ]]; then
+		rm usr/share/man/man1/google-chrome.1.gz || die
+		dosym ${MY_PN}.1 usr/share/man/man1/google-chrome.1
+	fi
+
+	pushd "${CHROME_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	rm "${CHROME_HOME}/libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "${CHROME_HOME}/libqt6_shim.so" || die
+	fi
+
+	local suffix=
+	[[ ${PN} == google-chrome-beta ]] && suffix=_beta
+	[[ ${PN} == google-chrome-unstable ]] && suffix=_dev
+
+	local size
+	for size in 16 24 32 48 64 128 256 ; do
+		newicon -s ${size} "${CHROME_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
+	done
+
+	pax-mark m "${CHROME_HOME}/chrome"
+}